VMware ThinApp Blog

But why wait?? Phil Helming (VB Scripter Extraordinaire) has put together a really nice VBS Script to be used within a login process which accommodates subfolders nicely!

Updates:

• Fixed issue where script wouldn't register apps in same folder as script.
• Correctly called cleanup code

' ////////////////////////////////////////////////////////////////////
' ///// DO NOT MODIFY THIS SCRIPT UNLESS SPECIFICALLY INSTRUCTED /////
' ////////////////////////////////////////////////////////////////////
'
' ////////////////////////////////////////////////////////////////////
'
' usage               : Execute this script manually or via logon script / desktop management
' description          : Script to search folder for *.exe files and run thinreg.exe against them
' author               : Phil Helmling (phelmling@vmware.com)
' filename          : Thinreg_recursively_v0.2.vbs
' version               : 0.2
' gpo               : n/a
' history:          : 17/09/09 initial release (Phillip Helmling)
'                      01/12/09 updated Iterate function as well as cleanup
' syntax               : none
' parameters          : none
' files               : none
'
' ////////////////////////////////////////////////////////////////////
     
     Option Explicit
     
'     Const ForReading     = 1, ForWriting = 2, ForAppending = 8, OverwriteExisting = True, NoOverwrite = False
     
'-----------------------------------------
'     Global Variables 
'-----------------------------------------

     Dim oShell     ' Shell for the script
     Dim oNet     ' Network for the script
     Dim oFSO     ' File System object for the script
     Dim oFile     ' File for the script
     Dim aFolder, aFolderRoot, aFile, SubFolder     ' Used to iterate through the fixed disks
     Dim incldic, incldic1, excldic, excldic1, a, a1, c, c1, i     ' Dictionaries
     Dim sPath, sCurrentPath ' Used for current directory and log file
     Dim sThinappshare, sThinregexe
     Dim f, Items, aItem

'-----------------------------------------
'     Objects 
'-----------------------------------------

     Set oShell      = WScript.CreateObject("Wscript.Shell")
     Set oNet      = WScript.CreateObject("Wscript.Network")
     Set oFSO      = WScript.CreateObject("Scripting.FileSystemObject")
     Set a           = WScript.CreateObject("Scripting.Dictionary")
     Set c           = WScript.CreateObject("Scripting.Dictionary")

'-----------------------------------------
'     Set Variables including source and destinations
'-----------------------------------------
     
     sPath = WScript.ScriptFullName
     sCurrentPath = Left(sPath, InStrRev(sPath, "\"))
     sThinappshare = sCurrentPath                     ' you can have the script start from the same directory as the script
'     sThinappshare = "\\SERVER\THINAPP_SHARE\"          ' or you can specify a drive:\folder structure or \\server\share

     sThinregexe = sThinappshare & "thinreg.exe"          ' you can run thinreg.exe from the same directory as the script
'     sThinregexe = "\\SERVER\THINAPP_SHARE\thinreg.exe"     ' or you can specify a drive:\folder structure or \\server\share

'-----------------------------------------
'     List extensions to search for in an array
'-----------------------------------------

     a.Add "a", "exe"
     incldic = a.Items   ' Get the items.
     For i = 0 To a.Count -1 ' Iterate the array.
          a1 = a1 & incldic(i) & ", " ' Create return string.
     Next
     incldic1 = a1

'-----------------------------------------
'     List directories to exclude
'-----------------------------------------

     ' Exclude all folders with the follow names
     c.Add "a", "System Volume Information"
     c.Add "b", "RECYCLER"
     c.Add "c", "Temp"
     c.Add "d", "Temporary Internet Files"
     c.Add "e", "plugins"
     c.Add "f", "tools"
     c.Add "g", "Other"
     c.Add "h", "MSOffice2k7"
     c.Add "i", "MSOffice97"

     excldic = c.Items   ' Get the items.
     For i = 0 To c.Count -1 ' Iterate the array.
          c1 = c1 & excldic(i) & ", " ' Create return string.
     Next
     excldic1 = c1

'-----------------------------------------
'      Main Program - Search all folders listed above
'-----------------------------------------

     Set aFolderRoot = oFSO.GetFolder(sThinappshare) 
     Call SearchFolder(aFolderRoot)

     Call Cleanup

'-----------------------------------------
'     Subs
'-----------------------------------------

     Sub SearchFolder(aFolder)
          On Error Resume Next
          Call Iterate(aFolder)
               
          ' Searching subfolders
          For Each SubFolder In aFolder.SubFolders
               SearchFolder SubFolder
          Next
     End Sub

     Sub Iterate(aFolder)
          On Error Resume Next
'          wscript.echo "Iterating through " & aFolder
          
          ' Folder Name not searched
          For Each aItem In c.Items
               If aFolder = sThinappshare Then
                    ' continue
               Else If InStr(excldic1, aFolder.Name) <> 0 Then Exit Sub
               End If
          Next

           For Each aFile In aFolder.Files
               If aFile.Name = "thinreg.exe" Then
                    ' do nothing
               ElseIf aFile.Name <> "" Then
                    If aFile.Name <> "" Then
                         If InStr(incldic1, Right(aFile.Name, 3)) <> 0 Then
'                              Wscript.Echo Chr(34) & sThinregexe & Chr(34) & " /q /norelaunch " & Chr(34) & aFile & Chr(34)
                              oShell.Run Chr(34) & sThinregexe & Chr(34) & " /q /norelaunch " & Chr(34) & aFile & Chr(34), 1, True ' register
'                              oShell.Run Chr(34) & sThinregexe & Chr(34) & " /u " & Chr(34) & aFile & Chr(34), 1, True ' unregister
                         Else
                         End If
                    End If
               End If
          Next
     End Sub

     Function Cleanup
          '      Clean up the objects and close the script
          Set oShell = Nothing
          Set oNet = Nothing
          Set oFSO = Nothing
          Set a = Nothing
          Set c = Nothing
          WScript.Quit
     End Function

Here's the script in it's entirety.
Download Thinreg_recursively_v0.2.vbs